Mr.Combet Webshell 🔥

View File Name : FilesByOwner_HTML.xsl

<?xml version="1.0" ?>
<!-- Copyright (C) 2004, Microsoft Corporation -->

<xsl:stylesheet 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt"
    xmlns:global="urn:srm-extension-obj"
    >


    <!-- XSLT parameters -->
    <xsl:param name="IsActiveHTML"/>
    <xsl:param name="RelativeFilesPath"/>


    <!-- Common definitions -->
    <xsl:include href="Common_HTML.xsl"/>        
    <xsl:include href="functions.xsl"/>        


    <!-- Main entry point -->
    <xsl:template match="StorageReport">
    <HTML>
    <head><xsl:comment>HEAD PLACEHOLDER</xsl:comment></head>
    <STYLE>
    BODY      {font-family:tahoma;font-size:0.75em}
    TD        {font-size:0.67em}
    TABLE     {border-collapse:collapse}
    </STYLE>
        <BODY id="BodyID">
        <p><xsl:apply-templates select="ReportHeader"/> </p>
        <p><xsl:apply-templates select="ReportSummary"/> </p>
        <p><xsl:apply-templates select="ReportGroupData"/> </p>
        </BODY>
    </HTML>
    </xsl:template>

    
    <!-- Table of contents -->
    <xsl:template name="TOC">
        
        <a href="#ReportTotals">
            <xsl:value-of select="$SrmStringRes_ReportTotals"/>
        </a><br/>
        <a href="#SizeByOwner">
            <xsl:value-of select="$SrmStringRes_SizeByOwner"/>
        </a><br/>
        <a href="#SizeByFileGroup">
            <xsl:value-of select="$SrmStringRes_SizeByFileGroup"/>
        </a><br/>
        
        <!-- Add report statistics per group -->
        <xsl:for-each select="/StorageReport/ReportGroupData">
            <xsl:call-template name="makeref"/>
        </xsl:for-each>
        
    </xsl:template>
    
    <xsl:template name="makeref">
        <a href="#ReportStatistics{@GroupID}">
            <xsl:value-of select="$SrmStringRes_Owner"/>
            <xsl:text>: </xsl:text>
            <xsl:value-of select="@Name"/>
            <xsl:text> </xsl:text>
            <xsl:value-of select="$SrmStringRes_Statistics"/>
        </a><br/>
    </xsl:template>
    


    <!-- Report Body rendering -->
    <xsl:template match="ReportGroupData">
        <a name="ReportStatistics{@GroupID}"/>
        <TABLE BORDER="1" borderColor="{$DarkBorderColor}"  
            WIDTH="37.5em" cellPadding="5">
            <xsl:if test="$IsActiveHTML = 'yes'">
                <xsl:attribute name="style">behavior:url(<xsl:value-of select="$RelativeFilesPath"/>sort.htc)</xsl:attribute>
            </xsl:if>
           
            <THEAD bgColor="{$TableHeaderBackground}" style="font:bold" linesPerItem="2">
                <TR noData="yes">
                    <TD colSpan="4" style="TEXT-ALIGN: center; font-size:0.83em" >
                        <xsl:value-of select="$SrmStringRes_StatisticsForFilesBy"/>
                        <xsl:text>'</xsl:text>
                        <xsl:value-of select="@Name"/>
                        <xsl:text>'</xsl:text>
                    </TD>
                </TR>
                <TR>
                    <TD rowSpan="2" sort="yes" style="{$THeadRightBorderStyle}">
                        <xsl:value-of select="$SrmStringRes_FileName"/>
                    </TD>
                    <TD colSpan="3" sort="yes" style="{$THeadBottomBorderStyle}">
                        <xsl:value-of select="$SrmStringRes_Folder"/>
                    </TD>
                    <TR>
                        <TD sort="yes" style="{$THeadRightBorderStyle}; TEXT-INDENT: 0.83em">
                            <xsl:value-of select="$SrmStringRes_SizeOnDiskMB"/>
                        </TD>
                        <TD sort="yes" style="{$THeadRightBorderStyle}">
                            <xsl:value-of select="$SrmStringRes_SizeMB"/>
                        </TD>
                        <TD sort="yes" >
                            <xsl:value-of select="$SrmStringRes_LastAccessed"/>
                        </TD>
                    </TR>
                </TR>
            </THEAD>
            <TBODY>
                <xsl:apply-templates select="Item"/>
            </TBODY>
        </TABLE>
        <p>
        <a href="#Top-report">
            <xsl:value-of select="$SrmStringRes_ToTopOf"/>
        </a>
        </p>
    </xsl:template>


    <xsl:template match="Item">
        <TR>
            <TD rowSpan="2" style="{$TBodyRightBorderStyle}">
                <xsl:value-of select="Name"/>
            </TD>
            <TD colSpan="3" style="{$TBodyBottomBorderStyle}">
                    <xsl:call-template name="DisplayFolder"/>
            </TD>
        </TR>
        <TR>
            <TD style="{$TBodyRightBorderStyle}; TEXT-INDENT: 0.83em">
                <xsl:value-of select="global:ConvertToMb(string(SizeAllocated))"/>
            </TD>
            <TD style="{$TBodyRightBorderStyle}">
                <xsl:value-of select="global:ConvertToMb(string(Size))"/>
            </TD>
            <TD>
                <xsl:value-of select="LastAccessTimeString"/>
            </TD>
        </TR>
    </xsl:template>



    <!-- Report Summary rendering -->
    <xsl:template match="ReportSummary">
        <xsl:call-template name="GroupReportTotals"/>
        <xsl:call-template name="SizeBySummaries"/>
    </xsl:template>



</xsl:stylesheet>